作成したグラフの項目軸（例えば折れ線グラフの場合には横軸）の項目名
やFontの大きさなどを変更したい場合にはAxisオブジェクト以下のプロパティー
を使用します。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
　１つ目のサンプルではシート上のグラフから項目名を取得します。
　　　（CategoryNamesプロパティー）
　２つ目のサンプルでは項目名に使用される文字の大きさを変更します。
　　　（TickLabelsプロパティー）
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
（前提）シート上のグラフ、コマンドボタン
　※サンプルでは折れ線グラフで実行を確認しています。

（サンプル１）
Private Sub CommandButton1_Click()

    Dim Var As Variant
    Dim i As Integer
    
    ActiveCell.Activate 'コマンドボタンからの実行に必要（97のみ）
    
    With ActiveSheet.ChartObjects(1).Chart
    
        '項目軸から項目を取得し、Variant型配列に格納
        'SeriesCollection.XValuesからも取得可能
        Var = .Axes(xlCategory).CategoryNames
        
        If Not IsArray(Var) Then
            MsgBox "項目を取得できませんでした"
            Exit Sub
        End If
        
        '配列の下限から上限までループ
        For i = LBound(Var) To UBound(Var)
            '取得したデータを変更（ここでは後ろ一文字を削る）
            Var(i) = Left(Var(i), Len(Var(i)) - 1)
        Next i
        
        '変更後のデータを項目名としてCategoryNamesに設定
        .Axes(xlCategory).CategoryNames = Var
    
    End With

End Sub

（サンプル２）
Private Sub CommandButton2_Click()

    ActiveCell.Activate'コマンドボタンからの実行に必要（97のみ）

    ActiveSheet.ChartObjects(1).Chart _
        .Axes(xlCategory).TickLabels.Font.Size = 9

End Sub